Algoritma Pemrograman 2 Menggunakan Visual Basic 6.0

Halo sobat semua. Kali ini saya akan share E-Book Algoritma Pemrograman 2 menggunakan VB. E-Book ini yang saya gunakan untuk belajar pemrograman pertama kali. Bahasanya mudah dimengerti dan banyak latihan-latihan yang dapat membantu kita untuk belajar pemrograman khususnya VB6.

E-Book ini ditulis oleh Bapak Achmad Basuki yang dikeluarkan oleh Politeknik Elektronika Negeri Surabaya - ITS. Semoga dapat membantu sobat semua untuk belajar VB6. Semoga bermanfaat.


DOWNLOAD E-BOOK

[VB 6.0] Internet Status

Kali ini saya akan share kode untuk mengecek koneksi internet. Hal ini mungkin dapat membantu dalam pembuatan suatu aplikasi yang membutuhkan koneksi internet. Oke langsung saja ya.

Buat sebuah modul dan ketik:

Private Declare Function InternetGetConnectedState Lib "wininet.dll" (ByRef lpdwFlags As Integer, ByVal dwReserved As Integer) As Integer

Public Function IsConnected() As Boolean
IsConnected = InternetGetConnectedState(0, 0)
End Function

Untuk menggunakan ketik:

IsConnected

Contoh bisa gunakan Command Button untuk mengeceknya dengan kode:

Private Sub Command1_Click()
If IsConnected = True Then
MsgBox "Connected", vbInformation + vbOKOnly, "Status"
Else
MsgBox "Not Connected", vbInformation + vbOKOnly, "Status"
End If
End Sub

DOWNLOAD PROJECT

[VB 6.0] Membuat Tray Icon

Kali ini saya akan share project membuat tray icon untuk aplikasi kita. Oke, daripada kelamaan silahkan langsung download source codenya pada link yang sudah saya sediakan dan dipelajari.


DOWNLOAD PROJECT

Membuat Browse Folder

Dalam membuat suatu aplikasi kadang kita memerlukan fungsi browse dialog. Nah, untuk membuat browse folder silahkan ikuti caranya sbb:

VB 6.0
Pada project anda, tambahkan Reference 'Microsoft Shell Controls And Automation' dan untuk memanggilnya ketik kode berikut:

Dim sh As New Shell
Dim fo As Shell32.Folder

On Error GoTo Ero
Set fo = sh.BrowseForFolder(Me.hWnd, "Pilih Folder", 0)
MsgBox fo.Self.Path 'folder yang terpilih
Ero:

VB .NET
Kode untuk memanggilnya adalah:

Dim dlg As New FolderBrowserDialog

dlg.Description = "Pilih Folder"

If dlg.ShowDialog() = 1 Then
MsgBox(dlg.SelectedPath) 'folder yg terpilih
End If

DOWNLOAD PROJECT VB 6.0
DOWNLOAD PROJECT VB .NET

[VB 6.0] ToolBar Warna

Bosan dengan tampilan toolbar standar di VB 6?? Coba anda modif sedikit dengan memberi warna dengan langkah-langkah sbb:

Buatlah sebuah Module lalu ketik:

Private Declare Function SetClassLong Lib "user32" Alias "SetClassLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwnewlong As Long) As Long
Private Declare Function OleTranslateColor Lib "oleaut32.dll" (ByVal lOleColor As Long, ByVal lHPalette As Long, ByRef lColorRef As Long) As Long
Private Declare Function CreateSolidBrush Lib "gdi32.dll" (ByVal crColor As Long) As Long
Private Declare Function DeleteObject Lib "gdi32.dll" (ByVal hObject As Long) As Long

Public Sub SetTlbColor(ByVal Tlb As Toolbar, ByVal Color As OLE_COLOR)
Dim l As Long
If OleTranslateColor(Color, 0, l) Then l = &HFFFF&
DeleteObject SetClassLong(Tlb.hwnd, -10, CreateSolidBrush(l))
End Sub

Untuk menggunakan, buat sebuah Form baru dengan kontrol ToolBar (Style=tbrFlat) didalamnya. Lalu ketikkan kode berikut di 'Form_Load':

SetTlbColor Toolbar1, vbBlue

DOWNLOAD PROJECT

Memanggil Fungsi CP (Control Panel)

Untuk memanggil beberapa fungsi yang ada pada control panel windows cukup mudah. Anda hanya perlu mengetikkan kode berikut:

VB 6.0

Shell "rundll32.exe shell32.dll,Control_RunDLL joy.cpl,,0", 1

VB .NET

Shell ("rundll32.exe shell32.dll,Control_RunDLL joy.cpl,,0", 1)

Nah, pada kode diatas saya mengambil contoh joy.cpl yaitu untuk memanggil Game Controller pada CP. Anda dapat mengganti joy.cpl dengan fungsi CP yang lain tinggal gantikan tulisan joy.cpl dengan nama file *.cpl yang lain. File *.cpl kebanyakan dapat anda temukan di lokasi instalasi Windows.

Untuk contoh yang lain silahkan langsung download source codenya saja. Semoga bermanfaat.


DOWNLOAD PROJECT VB 6.0
DOWNLOAD PROJECT VB .NET

[VB 6.0] Membuat Form Selalu di Depan

Bila anda ingin form dari aplikasi anda terletak didepan dengan form-form aplikasi lain atau form lain dari aplikasi yang sama, silahkan simak langkah-langkahnya dibawah ini.

Buatlah sebuah Module lalu ketik:

Public Declare Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal X As Long, ByVal Y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long

Public Sub FormOnTop(ByVal Frm As Form, ByVal State As Boolean)
SetWindowPos Frm.hwnd, IIf(State = True, -1, -2), 0, 0, 0, 0, &H1 Or &H2
End Sub

Untuk menggunakan, buat sebuah Form dan ketik kode berikut di bagian 'Form_Paint':

FormOnTop Me, True

DOWNLOAD PROJECT

Teks Judul Form Berjalan

Untuk membuat form yang teks judul formnya berjalan hanya diperlukan sebuah timer dengan properti Enabled = True dan Interval = 200. Untuk caranya adalah sbb:

VB 6.0
Di bagian '(Declarations)' Form ketik:

Dim s As String

Di bagian 'Form_Load' ketikkan :

s = "Isi dengan teks judul form"

Di bagian 'Timer1_Timer' ketik:

Caption = Left(s, 15) '15 adalah batasan karakter
s = Right(s, Len(s) - 1) & Left(s, 1)

VB .NET
Di bagian '(Declarations)' Form ketik:

Dim s As String = "Isi dengan teks judul form"

Di bagian 'Timer1_Tick' ketik:

Text = Microsoft.VisualBasic.Left(s, 15) '15 adalah batasan karakter
s = Microsoft.VisualBasic.Right(s, Len(s) - 1) & Microsoft.VisualBasic.Left(s, 1)

DOWNLOAD PROJECT VB 6.0
DOWNLOAD PROJECT VB .NET

[VB 6.0] Membuat Menu Ribbon

Apakah anda ingin menu aplikasi anda bertema ribbon seperti diatas??
Oke, tanpa lama-lama lagi dan daripada saya capek ngetiknya langsung saja download contoh projectnya dibawah ya...
Semoga bermanfaat


DOWNLOAD PROJECT

Membuat Label Berjalan

Kali ini kita akan belajar membuat label berjalan di form. Bahan-bahan yang harus disediakan adalah:
- 1 buah form
- 1 buah label
- 1 buah timer (Properti: Enabled = True dan Interval = 25)

Untuk cara membuatnya, simak langkah-langkah berikut:

VB 6.0
Ketikkan kode berikut pada Timer1_Timer:
Horizontal

Label1.Left = Label1.Left - 15
If (Label1.Left <= -(Label1.Width)) Or (Label1.Left >= Me.ScaleWidth) Then Label1.Left = Me.ScaleWidth

Vertikal

Label1.Top = Label1.Top - 15
If (Label1.Top <= -(Label1.Height)) Or (Label1.Top >= Me.ScaleHeight) Then Label1.Top = Me.ScaleHeight

VB .NET
Ketikkan kode berikut pada Timer1_Tick:
Horizontal

Label1.Left = Label1.Left - 2
If (Label1.Left <= -(Label1.Width)) Or (Label1.Left >= Me.ClientRectangle.Width) Then Label1.Left = Me.ClientRectangle.Width

Vertikal

Label1.Top = Label1.Top - 2
If (Label1.Top <= -(Label1.Height)) Or (Label1.Top >= Me.ClientRectangle.Height) Then Label1.Top = Me.ClientRectangle.Height

DOWNLOAD PROJECT VB 6.0
DOWNLOAD PROJECT VB .NET

[VB 6.0] Mouse Hover Button

Mouse hover ini digunakan untuk mengetahui apakah kursor mouse kita ada di suatu kontrol tertentu atau tidak. Sebenarnya tidak hanya dapat diterapkan pada kontrol button saja namun pada contoh kali ini saya akan menggunakan button ya.

Buat Module lalu ketikkan:

Private Declare Function GetCursorPos Lib "user32" (lpPoint As POINTAPI) As Long
Private Declare Function ScreenToClient Lib "user32" (ByVal hwnd As Long, lpPoint As POINTAPI) As Long
Private Declare Function ReleaseCapture Lib "user32" () As Long
Private Declare Function SetCapture Lib "user32" (ByVal hwnd As Long) As Long

Private Type POINTAPI
X As Long
Y As Long
End Type

Public Function MouseHover(Ctl As Control) As Boolean
Dim X As Single, Y As Single
Dim xyCursor As POINTAPI

SetCapture Ctl.hwnd
GetCursorPos xyCursor
ScreenToClient Ctl.hwnd, xyCursor

X = xyCursor.X * Screen.TwipsPerPixelX
Y = xyCursor.Y * Screen.TwipsPerPixelY

If X < 0 Or Y < 0 Or X > Ctl.Width Or Y > Ctl.Height Then
ReleaseCapture
MouseHover = False
Else
MouseHover = True
End If
End Function

Sebagai contoh penggunaan pada button, buat sebuah CommandButton (Style=Graphical),

lalu pada bagian 'Command1_MouseMove' ketikkan :
If MouseHover(Command1) Then
Command1.BackColor = vbBlue
Else
Command1.BackColor = vbButtonFace
End If

DOWNLOAD PROJECT

Gradient Background Form

Ingin form aplikasi anda menjadi tampak menarik dengan background gradien color seperti diatas??
Berikut ini akan saya berikan tutornya yah...

VB 6.0

Buatlah sebuah Module baru lalu ketikkan:

Enum GradMode
gmHorizontal = 0
gmVertical = 1
End Enum

Public Function GradientForm(ByVal Frm As Form, ByVal StartColor As Long, ByVal Endcolor As Long, ByVal Mode As GradMode)
Dim Rs As Integer, Gs As Integer, Bs As Integer
Dim Re As Integer, Ge As Integer, Be As Integer
Dim Rk As Single, Gk As Single, Bk As Single
Dim R As Integer, G As Integer, B As Integer
Dim i As Integer, j As Single

On Error Resume Next
Frm.AutoRedraw = True
Frm.ScaleMode = vbPixels

Rs = StartColor And (Not &HFFFFFF00)
Gs = (StartColor And (Not &HFFFF00FF)) \ &H100&
Bs = (StartColor And (Not &HFF00FFFF)) \ &HFFFF&
Re = Endcolor And (Not &HFFFFFF00)
Ge = (Endcolor And (Not &HFFFF00FF)) \ &H100&
Be = (Endcolor And (Not &HFF00FFFF)) \ &HFFFF&

j = IIf(Mode = gmHorizontal, Frm.ScaleWidth, Frm.ScaleHeight)
Rk = (Rs - Re) / j: Gk = (Gs - Ge) / j: Bk = (Bs - Be) / j

For i = 0 To j
R = Rs - i * Rk: G = Gs - i * Gk: B = Bs - i * Bk
If Mode = gmHorizontal Then
Frm.Line (i, 0)-(i - 1, Frm.ScaleHeight), RGB(R, G, B), B
Else
Frm.Line (0, i)-(Frm.ScaleWidth, i - 1), RGB(R, G, B), B
End If
Next
End Function

Untuk menggunakannya ketikkan kode berikut di bagian 'Form_Resize' dari Form:

GradientForm Me, vbRed, vbBlue, 0

VB .NET

Buatlah sebuah Module baru lalu ketikkan:

Public Sub GradientForm(ByVal Frm As Form, ByVal StartColor As Color, ByVal EndColor As Color, ByVal Mode As System.Drawing.Drawing2D.LinearGradientMode)
Dim a As New System.Drawing.Drawing2D.LinearGradientBrush(New RectangleF(0, 0, Frm.Width, Frm.Height), StartColor, EndColor, Mode)
Dim g As Graphics = Frm.CreateGraphics
g.FillRectangle(a, New RectangleF(0, 0, Frm.Width, Frm.Height))
g.Dispose()
End Sub

Untuk menggunakannya tambahkan kode berikut pada Form:

Protected Overrides Sub OnPaint(ByVal e As System.Windows.Forms.PaintEventArgs)
GradientForm(Me, Color.Red, Color.Blue, 0)
End Sub

Untuk menggunakannya ketikkan kode berikut di bagian 'Form_Resize' dari Form:

GradientForm(Me, Color.Red, Color.Blue, 0)

DOWNLOAD PROJECT VB 6.0
DOWNLOAD PROJECT VB .NET

[VB 6.0] Membuat Form Image

Anda ingin form aplikasi anda berbentuk image seperti contoh diatas??
Silahkan langsung download contoh projectnya saja ya. Terimakasih...


DOWNLOAD PROJECT

Notepad Otomatis

Kali ini saya akan share kode VB/ VB .Net untuk membuka dan menulis di notepad secara otomatis.

Buat Project baru dengan sebuah Form didalamnya, lalu ketikkan kode berikut di bagian '(Declarations)' dari Form :

Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Integer)

Cara memanggil dan menulis ketikkan :

Const p = "Teks anda"
Set SH = CreateObject("WScript.Shell")
Shell "notepad", vbNormalFocus
For i = 1 To Len(p)
Sleep 80
SH.SendKeys Mid(p, i, 1)
Next

DOWNLOAD PROJECT

[VB 6.0] Mengubah Teks Ke Suara

Berikut ini saya akan share tutorial agar teks dapat diubah menjadi suara. Kodenya adalah sbb:

Dim s
Set s = CreateObject("sapi.spvoice")
s.Speak "Teks anda"

DOWNLOAD PROJECT

[VB 6.0] Form Transparan

Ingin membuat form di VB 6.0 menjadi transparan seperti diatas??
Silahkan simak tutorialnya dibawah.

Buat sebuah Module baru lalu ketikkan :

Option Explicit

Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Function SetLayeredWindowAttributes Lib "user32" (ByVal hwnd As Long, ByVal crKey As Long, ByVal bAlpha As Byte, ByVal dwFlags As Long) As Long
Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long


Public Sub FadeForm(ByVal Frm As Form, ByVal Level As Byte)
On Error Resume Next
Dim msg As Long

msg = GetWindowLong(Frm.hwnd, -20) Or &H80000
SetWindowLong Frm.hwnd, -20, msg
SetLayeredWindowAttributes Frm.hwnd, 0, Level, &H2
End Sub

Selanjutnya di bagian Form yang akan dijadikan transparan, di 'Form_Load' ketikkan :

FadeForm Me, 125

Tingkat transparansi dapat diubah dengan mengganti nilai properti level dari 0 sampai 255.

DOWNLOAD PROJECT

Membuat Form About Model Windows

Ingin membuat form about yang sama seperti bawaan Windows pada aplikasi anda seperti diatas??
Berikut saya akan share kode sekaligus link download contoh projectnya.

VB 6.0

Pada bagian '(Declarations)' dari Form ketikkan:

Private Declare Function ShellAbout Lib "shell32.dll" Alias "ShellAboutA" (ByVal hWnd As Long, ByVal szApp As String, ByVal szOtherStuff As String, ByVal hIcon As Long) As Long

Untuk memanggilnya ketikkan :

ShellAbout Me.hWnd, "Nama Aplikasi", "Deskripsi", Me.Icon

VB .NET

Pada bagian '(Declarations)' dari Form ketikkan :

Private Declare Function ShellAbout Lib "shell32.dll" Alias "ShellAboutA" (ByVal hWnd As Integer, ByVal szApp As String, ByVal szOtherStuff As String, ByVal hIcon As Integer) As Integer

Untuk memanggilnya ketikkan :

ShellAbout(Me.Handle.ToInt32, "Nama Aplikasi", "Deskripsi", Me.Icon.Handle.ToInt32)

DOWNLOAD SC VB 6.0
DOWNLOAD SC VB .NET

Tentang Visual Basic

Microsoft Visual Basic (sering disingkat sebagai VB saja) merupakan sebuah bahasa pemrograman yang menawarkan Integrated Development Environment (IDE) visual untuk membuat program perangkat lunak berbasis sistem operasi Microsoft Windows dengan menggunakan model pemrograman (COM).

Visual Basic merupakan turunan bahasa pemrograman BASIC dan menawarkan pengembangan perangkat lunak komputer berbasis grafik dengan cepat.

Beberapa bahasa skrip seperti Visual Basic for Applications (VBA) dan Visual Basic Scripting Edition (VBScript), mirip seperti halnya Visual Basic, tetapi cara kerjanya yang berbeda.

Para programmer dapat membangun aplikasi dengan menggunakan komponen-komponen yang disediakan oleh Microsoft Visual Basic Program-program yang ditulis dengan Visual Basic juga dapat menggunakan Windows API, tapi membutuhkan deklarasi fungsi luar tambahan.

Dalam pemrograman untuk bisnis, Visual Basic memiliki pangsa pasar yang sangat luas. Sebuah survey yang dilakukan pada tahun 2005 menunjukkan bahwa 62% pengembang perangkat lunak dilaporkan menggunakan berbagai bentuk Visual Basic, yang diikuti oleh C++, JavaScript, C#, dan Java.


Perkembangan Visual Basic:
Visual Basic 1.0 dikenalkan pada tahun 1991. Konsep pemrograman dengan metode drag-and-drop untuk membuat tampilan aplikasi Visual Basic ini diadaptasi dari prototype generator form yang dikembangkan oleh Alan Cooper dan perusahaannya, dengan nama Tripod. Microsoft kemudian mengontrak Cooper dan perusahaannya untuk mengembangkan Tripod menjadi sistem form yang dapat diprogram untuk Windows 3.0, di bawah kode nama Ruby.

Tripod tidak memiliki bahasa pemrograman sama sekali. Ini menyebabkan Microsoft memutuskan untuk mengkombinasikan Ruby dengan bahasa pemrograman Basic untuk membuat Visual Basic.


Dari waktu ke waktu:
- Proyek Thunder dimulai.
- Visual Basic 1.0 dirilis untuk Windows pada Comdex/Windows Trade Show di Atlanta, Georgia pada Mei 1991.
- Visual Basic 1.0 untuk DOS dirilis pada September 1992. Bahasa pemrogramannya sendiri tidak terlalu kompatibel dengan Visual Basic untuk Windows, karena sesungguhnya itu adalah versi selanjutnya dari kompiler BASIC berbasis DOS yang dikembangkan oleh Microsoft sendiri, yaitu QuickBASIC. Antarmuka dari program ini sendiri menggunakan antarmuka teks, dan memanfaatkan kode-kode ASCII tambahan untuk mensimulasikan tampilan GUI.
- Visual Basic 2.0 dirilis pada November 1992. Lingkungan pemrogramannya lebih mudah untuk digunakan, dan kecepatannya lebih ditingkatkan.
- Visual Basic 3.0 dirilis pada musim semi 1993 dan hadir dalam dua versi: Standar dan Professional. VB3 juga menyertakan versi 1.1 dari Microsoft Jet Database Engine yang dapat membaca dan menulis database Jet/Access 1.x.
- Visual Basic 4.0 (Agustus 1995) adalah versi pertama yang dapat membuat program 32-bit seperti program 16-bit. VB4 juga memperkenalkan kemampuannya dalam membuat aplikasi non-GUI. Bila versi sebelumnya menggunakan kontrol VBX, sejak VB4 dirilis Visual Basic menggunakan kontrol OLE (dengan ekstensi file *.OCX), yang lebih dikenal kemudian dengan kontrol ActiveX.
- Dengan versi 5.0 (Februari 1997), Microsoft merilis Visual Basic eksklusif untuk versi 32-bit dari Windows. Para programmer yang lebih memilih membuat kode 16-bit dapat meng-impor program yang ditulis dengan VB4 ke versi VB5, dan program-program VB5 dapat dikonversi dengan mudah ke dalam format VB4.
- Visual Basic 6.0 (pertengahan 1998) telah diimprovisasi di beberapa bagian, termasuk kemampuan barunya, yaitu membuat aplikasi web. Meskipun kini VB6 sudah tidak didukung lagi, tetapi file runtime-nya masih didukung hingga Windows 7.


Sumber: Wikipedia